|
| 1 | +load("@aspect_rules_js//js:providers.bzl", "JsInfo", "js_info") |
| 2 | +load("@build_bazel_rules_nodejs//:providers.bzl", "DeclarationInfo", "JSEcmaScriptModuleInfo", "JSModuleInfo", "LinkablePackageInfo") |
| 3 | +load("@devinfra//bazel/ts_project:index.bzl", "strict_deps_test") |
| 4 | +load("@rules_angular//src/ts_project:index.bzl", _ts_project = "ts_project") |
| 5 | + |
| 6 | +def _ts_deps_interop_impl(ctx): |
| 7 | + types = [] |
| 8 | + sources = [] |
| 9 | + runfiles = ctx.runfiles(files = []) |
| 10 | + for dep in ctx.attr.deps: |
| 11 | + if not DeclarationInfo in dep: |
| 12 | + fail("Expected target with DeclarationInfo: %s", dep) |
| 13 | + types.append(dep[DeclarationInfo].transitive_declarations) |
| 14 | + if not JSModuleInfo in dep: |
| 15 | + fail("Expected target with JSModuleInfo: %s", dep) |
| 16 | + sources.append(dep[JSModuleInfo].sources) |
| 17 | + if not DefaultInfo in dep: |
| 18 | + fail("Expected target with DefaultInfo: %s", dep) |
| 19 | + runfiles = runfiles.merge(dep[DefaultInfo].default_runfiles) |
| 20 | + |
| 21 | + return [ |
| 22 | + DefaultInfo(runfiles = runfiles), |
| 23 | + ## NOTE: We don't need to propagate module mappings FORTUNATELY! |
| 24 | + # because rules_nodejs supports tsconfig path mapping, given that |
| 25 | + # everything is nicely compiled from `bazel-bin/`! |
| 26 | + js_info( |
| 27 | + target = ctx.label, |
| 28 | + transitive_types = depset(transitive = types), |
| 29 | + transitive_sources = depset(transitive = sources), |
| 30 | + ), |
| 31 | + ] |
| 32 | + |
| 33 | +ts_deps_interop = rule( |
| 34 | + implementation = _ts_deps_interop_impl, |
| 35 | + attrs = { |
| 36 | + "deps": attr.label_list(providers = [DeclarationInfo], mandatory = True), |
| 37 | + }, |
| 38 | +) |
| 39 | + |
| 40 | +def _ts_project_module_impl(ctx): |
| 41 | + # Forward runfiles. e.g. JSON files on `ts_project#data`. The jasmine |
| 42 | + # consuming rules may rely on this, or the linker due to its symlinks then. |
| 43 | + runfiles = ctx.attr.dep[DefaultInfo].default_runfiles |
| 44 | + info = ctx.attr.dep[JsInfo] |
| 45 | + |
| 46 | + # Filter runfiles to not include `node_modules` from Aspect as this interop |
| 47 | + # target is supposed to be used downstream by `rules_nodejs` consumers, |
| 48 | + # and mixing pnpm-style node modules with linker node modules is incompatible. |
| 49 | + filtered_runfiles = [] |
| 50 | + for f in runfiles.files.to_list(): |
| 51 | + if f.short_path.startswith("node_modules/"): |
| 52 | + continue |
| 53 | + filtered_runfiles.append(f) |
| 54 | + runfiles = ctx.runfiles(files = filtered_runfiles) |
| 55 | + |
| 56 | + providers = [ |
| 57 | + DefaultInfo( |
| 58 | + runfiles = runfiles, |
| 59 | + ), |
| 60 | + JSModuleInfo( |
| 61 | + direct_sources = info.sources, |
| 62 | + sources = depset(transitive = [info.transitive_sources]), |
| 63 | + ), |
| 64 | + JSEcmaScriptModuleInfo( |
| 65 | + direct_sources = info.sources, |
| 66 | + sources = depset(transitive = [info.transitive_sources]), |
| 67 | + ), |
| 68 | + DeclarationInfo( |
| 69 | + declarations = _filter_types_depset(info.types), |
| 70 | + transitive_declarations = _filter_types_depset(info.transitive_types), |
| 71 | + type_blocklisted_declarations = depset(), |
| 72 | + ), |
| 73 | + ] |
| 74 | + |
| 75 | + if ctx.attr.module_name: |
| 76 | + providers.append( |
| 77 | + LinkablePackageInfo( |
| 78 | + package_name = ctx.attr.module_name, |
| 79 | + package_path = "", |
| 80 | + path = "%s/%s/%s" % (ctx.bin_dir.path, ctx.label.workspace_root, ctx.label.package), |
| 81 | + files = info.sources, |
| 82 | + ), |
| 83 | + ) |
| 84 | + |
| 85 | + return providers |
| 86 | + |
| 87 | +ts_project_module = rule( |
| 88 | + implementation = _ts_project_module_impl, |
| 89 | + attrs = { |
| 90 | + "dep": attr.label(providers = [JsInfo], mandatory = True), |
| 91 | + # Noop attribute for aspect propagation of the linker interop deps; so |
| 92 | + # that transitive linker dependencies are discovered. |
| 93 | + "deps": attr.label_list(), |
| 94 | + # Note: The module aspect from consuming `ts_library` targets will |
| 95 | + # consume the module mappings automatically. |
| 96 | + "module_name": attr.string(), |
| 97 | + "module_root": attr.string(), |
| 98 | + }, |
| 99 | +) |
| 100 | + |
| 101 | +def ts_project( |
| 102 | + name, |
| 103 | + module_name = None, |
| 104 | + deps = [], |
| 105 | + interop_deps = [], |
| 106 | + tsconfig = None, |
| 107 | + testonly = False, |
| 108 | + visibility = None, |
| 109 | + ignore_strict_deps = False, |
| 110 | + enable_runtime_rnjs_interop = True, |
| 111 | + rule_impl = _ts_project, |
| 112 | + **kwargs): |
| 113 | + # Pull in the `rules_nodejs` variants of dependencies we know are "hybrid". This |
| 114 | + # is necessary as we can't mix `npm/node_modules` from RNJS with the pnpm-style |
| 115 | + # symlink-dependent node modules. In addition, we need to extract `_rjs` interop |
| 116 | + # dependencies so that we can forward and capture the module mappings for runtime |
| 117 | + # execution, with regards to first-party dependency linking. |
| 118 | + rjs_modules_to_rnjs = [] |
| 119 | + if enable_runtime_rnjs_interop: |
| 120 | + for d in deps: |
| 121 | + if d.startswith("//:node_modules/"): |
| 122 | + rjs_modules_to_rnjs.append(d.replace("//:node_modules/", "@npm//")) |
| 123 | + if d.endswith("_rjs"): |
| 124 | + rjs_modules_to_rnjs.append(d.replace("_rjs", "")) |
| 125 | + |
| 126 | + ts_deps_interop( |
| 127 | + name = "%s_interop_deps" % name, |
| 128 | + deps = [] + interop_deps + rjs_modules_to_rnjs, |
| 129 | + visibility = visibility, |
| 130 | + testonly = testonly, |
| 131 | + ) |
| 132 | + |
| 133 | + rule_impl( |
| 134 | + name = "%s_rjs" % name, |
| 135 | + testonly = testonly, |
| 136 | + declaration = True, |
| 137 | + tsconfig = tsconfig, |
| 138 | + visibility = visibility, |
| 139 | + deps = [":%s_interop_deps" % name] + deps, |
| 140 | + **kwargs |
| 141 | + ) |
| 142 | + |
| 143 | + if not ignore_strict_deps: |
| 144 | + strict_deps_test( |
| 145 | + name = "%s_strict_deps_test" % name, |
| 146 | + srcs = kwargs.get("srcs", []), |
| 147 | + deps = deps, |
| 148 | + ) |
| 149 | + |
| 150 | + ts_project_module( |
| 151 | + name = name, |
| 152 | + testonly = testonly, |
| 153 | + visibility = visibility, |
| 154 | + dep = "%s_rjs" % name, |
| 155 | + # Forwarded dependencies for linker module mapping aspect. |
| 156 | + # RJS deps can also transitively pull in module mappings from their `interop_deps`. |
| 157 | + deps = [] + ["%s_interop_deps" % name] + deps, |
| 158 | + module_name = module_name, |
| 159 | + ) |
| 160 | + |
| 161 | +# Filter type provider to not include `.json` files. `ts_config` |
| 162 | +# targets are included in `ts_project` and their tsconfig json file |
| 163 | +# is included as type. See: |
| 164 | +# https://github.com/aspect-build/rules_ts/blob/main/ts/private/ts_config.bzl#L55C63-L55C68. |
| 165 | +def _filter_types_depset(types_depset): |
| 166 | + types = [] |
| 167 | + |
| 168 | + for t in types_depset.to_list(): |
| 169 | + if t.short_path.endswith(".json"): |
| 170 | + continue |
| 171 | + types.append(t) |
| 172 | + |
| 173 | + return depset(types) |
0 commit comments